# /etc/csh.login

# System wide environment and startup programs, for login setup

if ($?PATH) then
	if ( "${path}" !~ */usr/X11R6/bin* ) then
		setenv PATH "${PATH}:/usr/X11R6/bin"
        endif
else
	if ( $uid == 0 ) then
		setenv PATH "/sbin:/usr/sbin:/usr/local/sbin:/bin:/usr/bin:/usr/local/bin:/usr/X11R6/bin"
	else
		setenv PATH "/bin:/usr/bin:/usr/local/bin:/usr/X11R6/bin"
	endif
endif

setenv HOSTNAME `/bin/hostname`
set history=1000

if ( ! -f $HOME/.inputrc ) then
	setenv INPUTRC /etc/inputrc
endif

if ( -d /etc/profile.d ) then
        set nonomatch
        foreach i ( /etc/profile.d/*.csh )
                if ( -r $i ) then
	                        if ($?prompt) then
	                              source $i
	                        else
	                              source $i >& /dev/null
	                        endif
                endif
        end
        unset i nonomatch
endif


# Set umask consistently with bash for loginshells (csh.login sourced
# after csh.cshrc unlike with bash profile/bashrc scripts and umask
# might be modified in profile.d csh scripts)
if ($?loginsh) then
  if ($uid > 99 && "`id -gn`" == "`id -un`") then
      umask 002
  else
      umask 022
  endif
endif